LML Editor Demo

Demo Editor for the Liturgical Markup Language

LML is used to create templates that are processed by Doxa to generate Orthodox Christian Liturgical Web Sites
/**
This is an example template written in the Liturgical Markup Language (LML).
Files written in LML have a .lml extension.
Any text editor can be used to write a template.
This example uses a Codemirror editor in a browser, using the Twilight theme.
The themes can be changed by the user.

Key words in LML are lowercase except when they combine multiple words,
in which case they use camel case, e.g.,

wed for Wednesday
modeOfWeek 

**/
ID: "ages/books/euchologion/liturgies/bk.liturgy.chrysostom" // used as id in database
// Properties
{  // if you wrap a block with braces { }, it can be folded / unfolded
type = "service" // valid types are service or book or block
title = "Divine Liturgy" // used for searching db for template
status = "draft"
day = 10
month = 12 // can also add year = 2022.  If the year is not specified, the current year is assumed.
css = "/ages/css/ages.css" // editor reads the css file so it knows what styles are valid
/**
 Page properties are used when generating PDFs. 
 Headers and footers are broken into three areas:
 left, center, and right.  
 
 When generating a document, up to three versions
 can be chosen, resulting in up to three columns
 in the body of the text.  Each column displays a specific
 version (e.g. the Greek text or a translation). The version
 used in column 1 is referred to as ver 1, in column 2 as 
 ver 2, and in column 3 as ver 3. When setting header or 
 footer information, the ver keyword indicates which version
 to use for the even and odd header and footer. This way, it
 is possible to use one version (e.g. Greek) on the even page
 header and footer and another (e.g. English) for odd pages.
 What if ver 2 or ver 3 is specified and a monolingual text is 
 being generated? The ver 2 or ver 3 will be converted to ver 1.
 If ver 3 is specified, and Doxa is generating a two language 
 service or book, ver 3 will be converted to ver 2. This is 
 called "down shifting" since the language number is shifted 
 down to a lower number. 

**/
pageHeaderFirst = none // turn of header for 1st page
pageHeaderEven = center @lookup sid "template.titles:li.pdf.header" ver 2
pageHeaderOdd = center @lookup sid "template.titles:li.pdf.header" ver 1
pageFooterFirst = none // turn off footer for 1st page
pageFooterEven = left @date lang 1 right @pageNbr
pageFooterOdd = left @pageNbr right @date ver 2
pageNbr = 1
 
/** 
 Directives begin with the @ symbol.
 For example:
   @date    - inserts the date of a service. 
   @h1      - inserts current h1 title
   @h2      - inserts current h2 title
   @h3      - inserts current h3 title
   @lookup  - inserts the results of looking up a value
              from the database using a specified ID (sid).
   @pageNbr - inserts the current page number.

  You can also insert literal text into a header or footer by using nid:
   nid "Page"    - inserts the word "Page" into the header or footer.
  Normally it would be best to use @Lookup with a sid to do this, but 
  for flexibility, you may also use a nid.
**/ 
/**
 In Doxa, database IDs for liturgical texts have this form:
     ltx/{library}/{topic}:{key}

     e.g. ltx/gr_gr_cog/actors:acPriest

     The library is gr_gr_cog
     The topic is actors
     The key is acPriest

 However, usually in templates we only specifiy the topic and key:

 sid - specific ID, e.g. sid "actors:acPriest"
 rid - relative ID, e.g. rid "oc.*:ocMO.Ode43.text"

The library is omitted so we can reuse templates with any language or version.

A sid is a specific topic:key for an ID. 
A rid is a topic:key for an ID that is calculated relative to the liturgical day properties, and works when the topic is da.*, eo.*, me.*, oc.*, pe.*, sy.*, tr.*, ty.*. A rid is transformed into a sid.

However, sometimes it is necessary to indicate a specific library, 
for example, for the credits part of a cover page:
 lid - long ID, e.g. lid "en_us_goa/properties:version.name"
**/ 
}
// Section 01
{
  p.actor sid "actors:Priest"
  p.dialog sid "eu.lichrysbasil:euLI.Key0109.text"
  p.dialog span.it sid "prayers:res04p"
}
// Section 02
{
  p.title span.desig sid "eu.lichrysbasil:euLI.Key0200.text"
  p.media sid "eu.lichrysbasil:euLI.Key0200.text"
  p.actor sid "actors:Deacon"
  insert "ages/blocks/LN/GreatLitany01"
  p.actor sid "actors:Priest" span.rubric sid "rubrical:InALowVoice"
  p.inaudible sid "eu.lichrysbasil:euLI.Key0201.text"
  p.actor sid "actors:Priest"
  p.dialog sid "prayers:exc01"
  p.dialog span.it sid "prayers:res04p"
}
// included css classes for spans are:
/**
span.it     = span.bk {color: black; font-style: italic; font-weight: normal}
span.bd     = span.bk {color: black; font-style: normal; font-weight: bold}
span.bk     = span.bk {color: black; font-style: normal; font-weight: normal}
span.rd     = span.bk {color: red; font-style: normal; font-weight: normal}
span.bkit   = span.bk {color: black; font-style: italic; font-weight: normal}
span.bkbd   = span.bk {color: black; font-style: normal; font-weight: bold}
span.bkitbd = span.bk {color: black; font-style: italic; font-weight: bold}
span.rdit   = span.bk {color: red; font-style: italic; font-weight: normal}
span.rdbd   = span.bk {color: red; font-style: normal; font-weight: bold}
span.rditbd = span.bk {color: red; font-style: italic; font-weight: bold}
**/
// more examples
{
  p.dialog sid "prayers:enarxis02" 
  // nid keyword means "no id" and will insert text verbatim
  p.dialog sid "prayers:pet02" span.rubric nid "(" sid "rubrical:InALowVoice" nid ")"
}
// css span names stay enabled until the next css span name or end of line is encountered.
// But, if you need to embed a span, you can use parentheses.
// You can optionally put spaces around the parentheses.
{
    // Ex 1: span.rubric continues until end of the line, no parentheses are needed.
    //       "a:b", "c:d", and "e:f" are all within the rubric span.
  p.verse sid "x:y" span.rubric sid "a:b" sid "c:d" sid "e:f"  
    // Ex 2: span.rubric continues until span.bk, and span.bk continues to the end of the line.
    //       "a:b" is in the rubric span, "c:d", and "e:f" are in the black span.
  p.verse sid "x:y" span.rubric sid "a:b" span.bk sid "c:d" sid "e:f"  
    // Ex 3:  span.rubric continues until the end of the line, 
    // but there is an embedded black span, so parentheses are needed.
    // "a:b" and "e:f" will be formatted as a rubric.
    // "c:d" will override the color property of the span.rubric
    // and be black.
  p.verse sid "x:y" span.rubric sid "a:b" (span.bk sid "c:d") sid "e:f"  
    //  Ex 4: for better readability, put spaces around parentheses.
  p.verse sid "x:y" span.rubric sid "a:b" ( span.bk sid "c:d" ) sid "e:f"  
}
/**
The only allowable use of an if exists statement is:
   if exists rid ....
A rid is a lookup relative to the liturgical day properties, 
and works when the topic is da.*, eo.*, me.*, oc.*, pe.*, sy.*, tr.*, ty.*
**/
if exists rid "oc.*:ocMO.Ode43.text" {
    p.verse sid "prayers:verse_Trinity.text"
    p.hymn rid "oc.*:ocMO.Ode42.text" @ver // @ver inserts the version name
  	p.title sid "prayers:Doxa"
  	p.hymn rid "oc.*:ocMO.Ode43.text" @ver
} else {
  	p.verse sid "prayers:verse_Trinity.text"
  	p.hymn rid "oc.*:ocMO.Ode41.text" @ver
  	p.title sid "prayers:Doxa"
  	p.hymn rid "oc.*:ocMO.Ode42.text" @ver
}
/**
    Keywords that are available to use in an if statement are:
        date 
        eothinon
        lukanCycleDay
        modeOfWeek
        nameOfDay
        sundayAfterElevationOfCross
        sundaysBeforeTriodion
        year
**/
// Example if statements include the following:
if date == nov 13 { // note: normally you would not use an if statement, but rather a rid with a wildcard topic: rid "me.*:meVE.Apolytikion1....
    p.title span.mode rid "me.m11.d13:meVE.Apolytikion1.mode" span.melody rid "me.*:meVE.Apolytikion1.melody"
    p.hymn rid "me.*:meVE.Apolytikion1.text" @ver
} 
if eothinon == 8 {
  p.chapVerse sid "le.go.eo.w08:leeoMA.Gospel.title_abbr" // instead of an if statement, could use rid "le.go.eo.*:leeoMA.Gospel.title_abbr"
}
if movableCycleDay == 1  {
  p.hymn rid "me.*:meMA.Ode1C13.text" @ver
}
if lukanCycleDay == 119  {
  p.hymn rid "me.*:meMA.Ode1C13.text" @ver
}
if sundayAfterElevationOfCross  == Sep 16  {  
  p.dialog span.rd sid "le.ep.me.m01.dSunAE:lemeLI.Epistle.title_abbr" @ver 
}
if sundaysBeforeTriodion  == 5  {
  p.dialog span.rd sid "le.ep.mc.d344:lemcLI.Epistle.title_abbr" @ver
}
if year == 2022  {
  p.hymn rid "me.*:meMA.Ode1C13.text" @ver
}
// A realm is an adhoc name or abbreviation set in the build configuration.
// Once it has been set, it can be used in conditional statements 
// to select the content to be included. In this example, the realm is goa,
// meaning Greek Orthodox Archdiocese.
if realm == "goa" {
  p.hymn rid "me.*:meMA.Ode1C13.text" @ver
} else {
  p.hymn rid "me.*:meMA.Ode1C12.text" @ver
}
// lml also supports if-else and nested if statements
if dayOfWeek == sun {
	 if modeOfWeek == 1 {
		  p.hymn sid "oc.m1.d1:ocMA.Lauds1.text" @ver
     } 
} else { 
	 p.hymn sid "oc.m2.d1:ocMA.Lauds1.text" @ver
}
// lml supports greater than (>), 
// greater than or equal (=>), 
// less than (<), 
// less than or equal (<=), 
// 'and' (&&)
// and 'or' (||)
if modeOfWeek >= 1  || dayOfWeek > sun {  
  p.hymn rid "me.*:meMA.Ode1C13.text" @ver 
} else {  
p.hymn rid "me.*:meMA.Ode1C12.text" @ver 
}
// Conditions can be grouped using parentheses.
// The example below means:
// if the mode of week is either 1 or 2
// and the day of week is Thursday, 
// then do ...
// else do ...
if (modeOfWeek == 1  || modeOfWeek == 2) &&  dayOfWeek == thu {
  p.hymn rid "me.*:meMA.Ode1C13.text" @ver 
} else {
  p.hymn rid "me.*:meMA.Ode1C12.text" @ver 
}
// if-else-if is supported
if modeOfWeek == 1 {
  p.hymn sid "oc.m1.d1:ocMA.Lauds1.text" @ver
} else if modeOfWeek == 2 {
  p.hymn sid "oc.m2.d1:ocMA.Lauds1.text" @ver
} else if modeOfWeek == 3 {
  p.hymn sid "oc.m3.d1:ocMA.Lauds1.text" @ver
} else {
  p.hymn sid "oc.m4.d1:ocMA.Lauds1.text" @ver
}
if modeOfWeek == 7  && (dayOfWeek == sun || dayOfWeek == thu )  {
  p.hymn rid "me.*:meMA.Ode1C13.text" @ver  
} else if  modeOfWeek == 2  && dayOfWeek == sun {
  p.hymn rid "me.*:meMA.Ode1C12.text" @ver 
} else {
    p.hymn rid "me.*:meMA.Ode1C11.text" @ver 
}
/** 
 switch cases that are based on a day can be a single day, e.g.:
     case 50
 Or, an inclusive range, e.g.:
     case 79 thru 84

 switch statements can be nested.
**/ 
switch movableCycleDay {
	case 79 thru 84 : {
		insert "Selector_FestalApolytikion/af/thomas"
  }  
	case 96 thru 102 : {
		insert "Selector_FestalApolytikion/af/midpentecost"
  }
	case 111 thru 118 : {
		insert "Selector_FestalApolytikion/af/ascension"
  }
	case 122 thru 126 : {
		insert "Selector_FestalApolytikion/af/pentecost"
  }
	default : {
		switch date {
			case jan 7 thru 14: { insert "ages/blocks/selectors/Selector_FestalApolytikion/af/Epiphany" }
			case feb 3 thru 9: { insert "ages/blocks/selectors/Selector_FestalApolytikion/af/Meeting" }
			case aug 7 thru 13: { insert "ages/blocks/selectors/Selector_FestalApolytikion/af/Transfiguration" }
			case aug 16 thru 23: { insert "ages/blocks/selectors/Selector_FestalApolytikion/af/Dormition" }
			case sep 9 thru 12: { insert "ages/blocks/selectors/Selector_FestalApolytikion/af/Theotokos_Birth" }
			case sep 15 thru 21: { insert "ages/blocks/selectors/Selector_FestalApolytikion/af/Cross" }
			case nov 22 thru 25: { insert "ages/blocks/selectors/Selector_FestalApolytikion/af/Entry" }
			case dec 26 thru 31: { insert "ages/blocks/selectors/Selector_FestalApolytikion/af/Christmas" }
		}
  }
}
/**
    Keywords available as the basis of a switch are:
        eothinon
        lukanCycleDay
        modeOfWeek
        nameOfDay
        sundayAfterElevationOfCross
        sundaysBeforeTriodion
        year
    A case statement can have comma separated conditions as shown below.
**/
switch modeOfWeek {
	case 1, 4, 5, 7, 8 : { // statements omitted for example }
	case 2, 3 : { // statements omitted for example }
	case 6 : { // statements omitted for example }
}
// Month and Day names are abbreviated to three lowercase letters
switch dayOfWeek {
	case mon, tue, wed, fri: {
		insert "ages/blocks/AP/da__/dayofweek1_"
		insert "ages/blocks/AP/gloryboth__.da_theotokion"
  }
	case thu: {
		insert "ages/blocks/AP/da__/dayofweek1_"
		insert "ages/blocks/TI/g/another"
		insert "ages/blocks/AP.ganame/Dec06__/nicholas_/hymn"
		insert "ages/blocks/AP/both__/da_theotokion"
  }
	case sat: {
		insert "ages/blocks/AP/da__/dayofweek1_"
		insert "ages/blocks/TI/g/another" 
		insert "ages/blocks/AP/da__/dayofweek2_/hymn" 
		insert "ages/blocks/AP/both__.da_theotokion"
  }
}
// If you want text to only appear in html pages and not PDF:
htmlOnly {
    p.bmc_collapse sid "template.titles:clps.additionallitanies.top" 
}
// If you want text to only appear in PDF and not in html pages:
pdfOnly {
   insert "blocks/pdf/bl.pdf.cover.ma.me"
}
// You can have multiple statements inside the htmlOnly block and pdfOnly block.
// The htmlOnly and pdfOnly blocks can occur multiple times and in any place in a template.
// Statements not enclosed in an htmlOnly or pdfOnly block will occur in both html and PDF.

// Additional Directives
month = 12 day = 31 // change the date to the current year, December 31.
restoreDate // restore the date to the one indicated at the beginning of the template

realm = "oca" // change the value of the realm, overriding the one set in the configuration
restoreRealm // restore the realm to the one set in the configuration

// You can add a hypertext link in the html and pdf as follows:
version = 2 // switch to single column, specifying the column to use
p.verse a.link href "https://ocmc.org"  label "OCMC" // target is set to _blank
restoreVersion // switch back to multi-column mode

// Expandable sections
// You can use h1, h2, and h3 to insert expandable sections into your content.
// Like p and span, the class employed must be specified in the stylesheet.

h1.section sid "titles:ti.Trisagion" {
	// anything inside these curly-braces will collapse or expand when the heading is clicked
	p.actor sid "actors:ac.Reader"
	p.reading sid "prayers:pr.HolyGod.text" span.red sid "rubrical:ru.Thrice"
}

h2.prayers sid "ho.ho21:hoPrayer.title" {
	p.reading sid "ho.ho21:hoPrayer.Key101.text"
}

// h1 is a top level section. you can put an h2 subsection inside it
// however you cannot have an h1 inside an h2.
h1.section sid "titles:ti1" {
	p.reading rid "oc.*:ocMO.Ode43.text"
	h2.section sid "titles:after" {
		//h3 can be inside of h2 but not vice-versa
		h3.section sid "titles:ti" {
			p.actor sid "actors:ac.Priest"
		}
	}
}